namespace;
include rt, run;

// growing the language from inside a program, while it compiles

// x |> f calls f(x). on a stack machine that's just "call": the value is
// already on the stack, under f's address.
immediate fn pipe_op() { run.next(); run.add_binop("|>", 1, "c"); return 0; }
pipe_op

// unless (c) stmt
immediate fn unless() {
	let a;
	run.next(); run.expect(run.intern("(")); run.plainuse(run.expr()); run.rval(); run.expect(run.intern(")"));
	run.emitseq(run.useq[0], run.ulen[0]);		// not
	a = run.hole(); run.op(run.O_JZ);
	run.substmt();
	run.setlit(a, run.here);
	return 0;
}
// assert (c): the failure message carries the line it was written on
void assert_fail(int line) { rt.put_s("assertion failed on line "); rt.put_n(line); rt.put_c(10); rt.halt(); return; }
immediate fn assert() {
	let a, l = run.tline;
	run.next(); run.expect(run.intern("(")); run.plainuse(run.expr()); run.rval(); run.expect(run.intern(")"));
	run.emitseq(run.useq[0], run.ulen[0]);		// not: the jump below skips the failure when it holds
	a = run.hole(); run.op(run.O_JZ);
	run.lit(l); run.callname(run.intern("assert_fail")); run.op(run.O_DROP);
	run.setlit(a, run.here);
	return 0;
}
// times N { body }: the body pasted N times, at compile time
immediate fn times() {
	let n, b, i = 0;
	run.next(); n = run.tv; run.next();
	b = run.grab();
	while (i < n) { run.feed(run.qdup(b)); i++; }
	rt.free(b);
	return 0;
}

fn double(x) { return x * 2; }
fn inc(x) { return x + 1; }
void main() {
	rt.put_n(5 |> double |> inc |> double); rt.put_c(10);
	unless (1 > 2) rt.put_s("one isn't bigger than two\n");
	times 3 { rt.put_c('*'); }
	rt.put_c(10);
	assert(double(4) == 8);
	assert(inc(1) == 3);
	return;
}