blob: e4d91c5fdd8d9c4a308268f922a002b5f8089fcc (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
// growing the language from inside a program, while it compiles
// x |> f calls f(x). on a stack machine that's just "call": the value is
// already on the stack, under f's address.
immediate fn pipe_op() { next(); add_binop("|>", 1, "c"); return 0; }
pipe_op
// unless (c) stmt
immediate fn unless()
{
let a;
next(); expect(intern("(")); plainuse(expr()); rval(); expect(intern(")"));
emitseq(useq[0], ulen[0]); // not
a = hole(); op(O_JZ);
substmt();
setlit(a, here);
return 0;
}
// assert (c): the failure message carries the line it was written on
fn assert_fail(int line) { puts("assertion failed on line "); putn(line); putc(10); halt(); return 0; }
immediate fn assert()
{
let a, l = tline;
next(); expect(intern("(")); plainuse(expr()); rval(); expect(intern(")"));
emitseq(useq[0], ulen[0]); // not: the jump below skips the failure when it holds
a = hole(); op(O_JZ);
lit(l); callname(intern("assert_fail")); op(O_DROP);
setlit(a, here);
return 0;
}
// times N { body }: the body pasted N times, at compile time
immediate fn times()
{
let n, b, i = 0;
next(); n = tv; next();
b = grab();
while (i < n) { feed(qdup(b)); i++; }
free(d*b);
return 0;
}
fn double(x) { return x * 2; }
fn inc(x) { return x + 1; }
fn main()
{
putn(5 |> double |> inc |> double); putc(10);
unless (1 > 2) puts("one isn't bigger than two\n");
times 3 { putc('*'); }
putc(10);
assert(double(4) == 8);
assert(inc(1) == 3);
return 0;
}
|
