1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
namespace;
include rt, run;
// types: structs, a generic container, and looking at it all through reflection.
// a pointer type has its star after the type, like c: int*, point*, vec<T>*.
typecheck on;
struct point { int x, y; };
struct vec<T> { int len, cap; T* items; };
vec<T>*.u mkvec<T>(int cap) {
vec<T>* v = rt.new(vec<T>);
v.cap = cap;
v.items = rt.new(T, cap);
return v;
}
// x is given away (.d): the vector's memory holds it from now on, and the
// collector looks after it
bool push<T>(vec<T>* v, T.d x) {
if (v.len == v.cap) { rt.free(x); return 0; }
v.items[v.len] = d*x;
v.len++;
return 1;
}
void show(word t) {
let i = 0;
run.tprint(t); rt.put_s(" is "); rt.put_n(run.tsize(t)); rt.put_s(" words: ");
while (i < run.tnfields(t)) {
if (i) rt.put_s(", ");
rt.put_s(run.tfname(t, i)); rt.put_s(" "); run.tprint(run.tftype(t, i));
i++;
}
rt.put_c(10);
return;
}
int main() {
vec<point*>* v = mkvec<point*>(4);
int i = 0;
while (i < 3) {
point* p = rt.new(point);
p.x = i; p.y = i * i;
push(v, p);
i++;
}
rt.put_s("last: "); rt.put_n(v.items[2].y); rt.put_c(10);
show(typeof(point));
show(typeof(*v));
rt.put_s("push is "); run.tprint(run.sigof(push)); rt.put_c(10);
// each set of type arguments gets its own copy of mkvec, so what it stamped is vec<point*>
rt.put_s("the heap says v is a "); run.tprint(rt.typeof_obj(v)); rt.put_s(", and v.items[0] is a "); run.tprint(rt.typeof_obj(v.items[0])); rt.put_c(10);
return 0;
}
|
